- We first create a dialog using CreateMessageDialog
- This function will return a form object with dialog
- In this object we can add a ProgressBar
- We also add a Timer object for dynamic progress bar position update
- Show dialog using ShowModal
- Handle the OnTimer event of the TTimer component to see if the elapsed number of seconds has passed - if so, we close the dialog by setting the ModalResult property, from code, to mrCancel.
- If not, we use StepIt to update the progressbar.
Drop a TButton (Button1) on a form (Form1), and try the next code:
~~~~~~~~~~~~~~~~~~~~~~~~~
procedure TForm1.Button1Click(Sender: TObject) ;
var
AMsgDialog : TForm;
AProgressBar : TProgressBar;
ATimer : TTimer;
begin
AMsgDialog := CreateMessageDialog('Quickly! Answer Yes or No!', mtWarning, [mbYes, mbNo]) ;
AProgressBar := TProgressBar.Create(AMsgDialog) ;
ATimer := TTimer.Create(AMsgDialog) ;
with AMsgDialog do
try
Tag := 10; //seconds!
Caption := 'You have 10 seconds';
Height := 150;
with AProgressBar do begin
Name := 'Progress';
Parent := AMsgDialog;
Max := AMsgDialog.Tag; //seconds
Step := 1;
Top := 100;
Left := 8;
Width := AMsgDialog.ClientWidth - 16;
end;
with ATimer do
begin
Interval := 1000;
OnTimer:=DialogTimer;
end;
case ShowModal of
ID_YES: ShowMessage('Answered "Yes".') ;
ID_NO: ShowMessage('Answered "No".') ;
ID_CANCEL: ShowMessage('Time up!')
end;//case
finally
ATimer.OnTimer := nil;
Free;
end;
end;
//make sure you add this function's header in the private part of the TForm1 type declaration.
procedure TForm1.DialogTimer(Sender: TObject) ;
var
aPB : TProgressBar;
begin
if NOT (Sender is TTimer) then Exit;
if ((Sender as TTimer).Owner) is TForm then
with ((Sender as TTimer).Owner) as TForm do
begin
aPB := TProgressBar(FindComponent('Progress')) ;
if aPB.Position >= aPB.Max then
ModalResult := mrCancel
else
aPB.StepIt;
end;
end;
~~~~~~~~~~~~~~~~~~~~~~~~~
Note: you'll also want to look at
Delphi tips navigator:
» Enter key or Return key?
« TIPS
