1. Handle the OnCellClick event of a DBGrid (Name := 'DBGrid1') to start the drag operation:

procedure TForm1.DBGrid1CellClick(Column: TColumn);
begin
  DBGrid1.BeginDrag(true);
end;

2. Specify that a Memo control (Name := 'Memo1') can accept data from a DBGrid, using the OnDragDrop event of a Memo:

procedure TForm1.Memo1DragOver(
  Sender, Source: TObject; X, Y: Integer;
  State: TDragState; var Accept: Boolean);
begin
  Accept := Source IS TDBGrid;
end;

3. Finally, handle the OnDragDrop of a Memo control to process data being dropped. We'll add the code to add the values of all the fields of the current record to a Memo control:

procedure TForm1.Memo1DragDrop(
  Sender, Source: TObject; 
  X, Y: Integer);
var i : integer;
begin
  Memo1.Clear;

  for i := 0 to -1 + DBGrid1.FieldCount do
  begin
    Memo1.Lines.Add(DBGrid1.Fields[i].AsString);
  end;
end;

Once you have a running application, click on a row in a DBGrid (to make the row/record active) then click inside the Memo control: Memo gets filled with the values of the fields from the selected (dragged record).

Dragging TO a DBGrid

Suppose you have a ListBox filled with items, and want to enable a user to drag an item to a particular cell (e.g. to edit one particular field) of a DBGrid - to change the value of a specific field. How do you determine the exact row and the exact cell of a DBGrid where the user has finished the drag operation?

As discussed in the "accessing protected members of a component" article, many Delphi components have useful properties and methods that are marked invisible ("protected") to a Delphi developer.

When a user finishes the drag operation and drops a value over a cell in a DBGrid, we have to set the active record, place the underlying dataset into edit mode, and assign a value to a particular field.

Here's the code needed to handle dragging to a DBGrid:

1. Since we are dropping items from a ListBox control, by handling the OnDragOver of a DBGrid we specify that only items from a ListBox are acceptable to be dropped on a DBGrid:

procedure TForm1.DBGrid1DragOver(
  Sender, Source: TObject; X, Y: Integer;
  State: TDragState; var Accept: Boolean);
begin
  Accept := Source IS TListBox;
end;

2. The tricky part goes in the OnDragDrop event handler for DBGrid:

procedure TForm1.DBGrid1DragDrop(
  Sender, Source: TObject; X, Y: Integer);
var
  gc : TGridCoord;
  s : string;
begin
  gc := THackDBGrid(DBGrid1).MouseCoord(X,Y);
  if (gc.X > 0) AND (gc.Y > 0) then
  begin
    if ListBox1.ItemIndex = -1 then Exit;
    s := ListBox1.Items[ListBox1.ItemIndex];

    with THackDBGrid(DBGrid1) do
    begin
      DataSource.DataSet.MoveBy (gc.Y - Row);
      DataSource.DataSet.Edit;
      Columns.Items[-1 + gc.X].Field.AsString := s;
    end;
  end;
end;

Note: We first use the protected hack to get our hands on the protected MouseCoord method to access the row and column of a DBGrid. This technique is explained in the Selecting and highlighting a row in a DBGrid - "OnMouseOverRow" article. If the target is not the first row (where column titles are by default) and not the first column (where row indicator is by default) we set the current row using the MoveBy method and the Row property. Next, dataset is put into edit mode. Finally, the value of the target field is assigned using the selected item from the ListBox.

That's it. If you are looking for more DBGrid related article, check the "TDBGrid to the MAX" collection. More drag and drop ideas can be found here: dragging and dropping with Delphi.