procedure TForm1.AddItemButtonClick(
  Sender: TObject);
const
  pbColumnIndex = 1;
  pbMax = 100;
var
  li : TListItem;
  lv : TListView;
  pb : TProgressBar;
  pbRect : TRect;
begin
  lv := ListViewEx1;

  //create new ListItem (for the lv)
  li := lv.Items.Add;
  li.Caption := 'Item ' + IntToStr(lv.Items.Count);

  //create a ProgressBar, place it in the second column
  pb := TProgressBar.Create(nil);
  pb.Parent := lv;
  li.Data := pb;
  pbRect := li.DisplayRect(drBounds);
  pbRect.Left := pbRect.Left + 
                 lv.Columns[-1 + pbColumnIndex].Width;
  pbRect.Right := pbRect.Left + 
                  lv.Columns[pbColumnIndex].Width;
  pb.BoundsRect := pbRect;
end; //AddItemButtonClick

procedure TForm1.RemoveItemButtonClick(
  Sender: TObject);
var
  lv : TListView;
  li : TListItem;
  i, idx : integer;
  pb : TProgressBar;
begin
  lv := ListViewEx1;

  li := lv.Selected;

  if li <> nil then
  begin
    idx := li.Index;
    TProgressBar(li.Data).Free;
    lv.Items.Delete(idx);

    //move bars up
    for i := idx to -1 + lv.Items.Count do
    begin
      li := lv.Items.Item[i];
      pb := TProgressBar(li.Data);
      pb.Top := pb.Top - 
                (pb.BoundsRect.Bottom - 
                 pb.BoundsRect.Top);
    end;
  end;
end; //RemoveItemButtonClick

procedure TForm1.Timer1Timer(
  Sender: TObject);
var
  idx : integer;
  pb: TProgressbar;
  lv : TListView;
begin
  lv := ListViewEx1;

  if lv.Items.Count = 0 then Exit;
  
  //randomly pick an item and 
  //increment it's progress position 
  idx := Random(lv.Items.Count);
  pb := TProgressBar(lv.Items[idx].Data);
  if pb.Position < pb.Max then
    pb.StepIt
  else
    pb.Position := 0;
end;//Timer1Timer

procedure TForm1.ListViewEx1EndColumnResize(
  sender: TCustomListView;
  columnIndex,
  columnWidth: Integer);
var
  lv : TListViewEx;
  idx : integer;
  pb : TProgressBar;
begin
  lv := ListViewEx1;

  //first column
  if columnIndex = 0 then
  begin
    for idx := 0 to -1 + lv.Items.Count do
    begin
      pb := TProgressBar(lv.Items[idx].Data);
      pb.Left := columnWidth;
    end;
  end;

  //progress bar column
  if columnIndex = 1 then
  begin
    for idx := 0 to -1 + lv.Items.Count do
    begin
      pb := TProgressBar(lv.Items[idx].Data);
      pb.Width := columnWidth;
    end;
  end;
end;