Every Control Panel application exports the standard entry-point function, named CPlApplet. This function receives requests, in the form of messages (like "CPL_SOMETHING"), and carries out the requested work, such as initializing the application, returning a number of dialog boxes it supports, providing information about a specified dialog box, and closing the application.

Therefore, after we have dynamically loaded the CPL, in order to look inside the CPL application we need to "find" the CPlApplet function. This is done by calling the GetProcAddress API call.

Once we lay our hands on the CPlApplet function, we use it to grab the information about the Contol Panel Application we want. First, we send it the CPL_GetCount message to get the number of dialog boxes (Applets) it carries. Remember that each .CPL file is an application that can hold more than one Applet. Second, for each Applet, we send the CPL_INQUIRE message that fills the CPLInfo structure. This structure contains resource information (such as the name of the applet, description and icon) and an application-defined value for a dialog box supported by a Control Panel application. Finally, we use LoadIcon and LoadString API calls to get the information we are interested in.

When we have finished with the Control Panel application (the CPL file), we unload it using the FreeLibrary function.

Uh, the "story" above looks quite messy ;) Don't runaway, Delphi code looks much more friendly.

   Control Panel Folder - Delphi Way

The ProcessCPLApplet function
Here's the "main" function in the project, the one that receives one Control Panel application (parameter sCPLName: CPL file name), processes each Applet inside the application, and places the information inside the ListView component.

procedure TMainForm.ProcessCPLApplet(sCPLName : string);
var
   H: HInst;
   CPlApplet: TCPLApplet;
   NumberOfApplets: Integer;
   AppletInfo: TCPLInfo;
   I: Integer;
   Name, Comment: string;
   TheIcon : TIcon;
begin
   // Load CPL
   H := LoadLibrary(PChar(sCPLName));
   if H <> 0 then
   try
     // Locate CPlApplet Function from Module
     CPlApplet:= GetProcAddress(H, 'CPlApplet');
     if Assigned(CPlApplet) then
     begin
       // Get Number of Applets contained in the .cpl file
       NumberOfApplets:= CPlApplet(Application.Handle, CPL_GetCount, 0, 0);
       for i := 0 to -1 + NumberOfApplets do
       begin
         // Pick Name and Comment
         CPlApplet(Application.Handle, CPL_INQUIRE, i, Longint(@AppletInfo));
         Name:= LoadStringFromModule(H, AppletInfo.idName);
         Comment:= LoadStringFromModule(H, AppletInfo.idInfo);
         // Display info
         if Name <> '' then
         begin
           with lvCPL.Items.Add do
           begin
            TheIcon:=TIcon.Create;
            try
              //grab the Applet icon
              TheIcon.Handle:=LoadIcon(H, PChar(AppletInfo.idIcon));
              ImageIndex := cplIcons.AddIcon(TheIcon);
            finally
              TheIcon.Free;
            end;

            //add to ListView
            Caption := Name;
            SubItems.Add(Comment);
            SubItems.Add(sCPLName);
           end;
         end;
       end;
     end;
   finally
     FreeLibrary(H);
   end;
end;

Note: the TCPLApplet and the TCPLInfo types are defined in the Delphi CPL.pas unit, which you will have to include in the uses clause. The LoadStringFromModule is a function defined in the project used to extract the string value (stored as a resource) inside the CPLInfo structure.

All set, we have a Delphi clone of the Windows Control Panel folder, now we proceed to executing a particular applet!