What I will try to show you here, is that with a little knowledge and creativity, you can turn Delphi's own grids into nice, professional looking grids. There are three main topics that I will show you. First of all we should take a look on how to fix-up the column header. Then I will show how to add clickable buttons and checkboxes inside cells. And last I will show a way to simulate merged cells. Below I have included a screenshot from the sample application that comes with the article, showing some ideas of what you can do with a standard TStringGrid.

Doing some header-makeup

I usually have a 'UpdateGrid()'-method that I call after adding or deleting data records. First of all this method updates the RowCount property. Then it checks the FixedRows property, and finally invalidates the grid. As you can see from the code listing, the first step is rather trivial. In a real-world situation I would have read the row count from the data holder, but here I have passed it as a parameter since we don't have any data.

procedure TfrmMain.UpdateGrid(rowCount: integer);
begin
 //Update rowcount
 gridOwnerDraw.RowCount := rowCount;
 
  //If rowcount < 2 fixedrows is set to 0, 
  //so we have to set it back if rowcount grows:
  if gridOwnerDraw.RowCount > 1 then
    gridOwnerDraw.FixedRows := 1;
 
  //Invalidate grid
  gridOwnerDraw.Invalidate;
end;

The next step is the drawing and involves some more work. First of all we calculate the position for the text. Then we set all the properties of the canvas object and clear the cell. Next thing we use the DrawText method provided with the Windows API. This method has some very usable flags that we can provide. Take a look at the documentation to get a complete description. Here I have used four flags that give us a single line of text, centered both vertical and horizontal and with an ellipse ('...') at the end if the cell is too small to fit all of the text. At the end of the method, we draw the lines around the cell to simulate a 3D-look.

procedure TfrmMain.gridOwnerDrawDrawCell
(Sender: TObject; ACol, ARow: Integer; 
Rect: TRect; State: TGridDrawState);
  //Make some text to display in cell
  function GetText(ACol, ARow: integer): string;
  begin
    if ARow = 0 then
      result := format('Header %d', [ACol])
  end;
var
  txtRect: TRect;
  str: string;
begin
  //If header is to be drawn:
  if ARow = 0 then
  begin
    //Textplacement:
    txtRect := Rect;
    txtRect.Left := Rect.Left + TXT_MARG.x;
    txtRect.Top := Rect.Top + TXT_MARG.y;
    //Setting canvas properties and erasing old cellcontent:
    with gridOwnerDraw.Canvas do
    begin
      Brush.Color := clBtnFace;
      Font.Style := [];
      Font.Color := clWindowText;
      Font.Name := gridOwnerDraw.Font.Name;
      Font.Size := gridOwnerDraw.Font.Size;
      FillRect(rect);
    end;
    //Drawing text:
    str := GetText(ACol, ARow);
    DrawText(gridOwnerDraw.canvas.Handle, PChar(str),  
             length(str), txtRect, 
             DT_SINGLELINE or DT_LEFT or DT_VCENTER or DT_END_ELLIPSIS);
    //Drawing 3D-frame:
    with gridOwnerDraw.Canvas do
    begin
      Pen.Style := psSolid;
      Pen.Width := 1;
      Pen.Color := clWhite;
      Polyline([point(rect.left, rect.bottom),
               rect.TopLeft, point(rect.Right, rect.top)]);
      Pen.Color := clBtnShadow;
      Polyline([point(rect.left+1, rect.bottom-1), 
               point(rect.right-1, rect.bottom-1), 
               point(rect.Right-1, rect.Top+1)]);
    end;
  end;
end;

It is possible to include components for editing inside cells, but if a checkbox or a simple button is all you need you can easily do it with some custom drawing...